Към съдържанието

Настройки за бисквитки

Изберете кои видове бисквитки разрешавате. Можете да промените избора си по всяко време чрез „Настройки за бисквитки“ в долната част на всяка страница. Декларация за поверителност

Необходими

Винаги включени

Нужни са за вход, за запазване на количката и на Вашите избори. Те са винаги включени.

Кои бисквитки?
  • weboke_sessie, weboke_klant, weboke_remember: Вашата сесия и оставането в акаунта
  • weboke_basket: Вашата количка
  • wkBtwIncl: показване на цените с или без ДДС
  • wok_cookies: Вашият избор за бисквитките, 12 месеца

Измерват коя реклама води до посещение или поръчка, за да не плащаме за реклами без резултат.

Кои бисквитки?
  • Google Ads чрез Google Tag Manager (_gcl_au, _gcl_aw), до 90 дни
  • OpenAI Ads, реклами в ChatGPT
  • wok_aff: кой партньор Ви е препратил към нас (партньорска програма), 60 дни

4,6

Държава и език

Всяка държава има собствен сайт, с цените и ДДС на тази държава.

Преглед

Сумиране на оборота по месеци или за период със SUMIFS

Касовата книга, списъкът с продажби или отчетът за работните часове съдържат дата на всеки ред. Това, което искате да знаете, е сумата за месец, за тримесечие или между две дати, евентуално и по продукти. Със SUMIFS и две условия за дата можете да създадете такова обобщение, което остава вярно и когато се добавят нови редове. Обобщената таблица също може да го направи (вижте Обобщена таблица по месеци, тримесечия или седмици); SUMIFS е по-удобна, когато обобщението трябва да запази постоянна форма, например за отчет или бюджет.

Като пример използваме продажбите на Bloemisterij Het Zonnetje в работния лист Verkoop: в A е датата, в B продуктът, в C категорията и в D сумата, от ред 2 до ред 300 включително.

Стъпка 1: ред с месеци

Създайте работен лист Overzicht. Вместо да въвеждате дванадесет дати, една формула създава всички. Въведете в A2:

=EDATE(DATE(2026;1;1);SEQUENCE(12;1;0))

SEQUENCE(12;1;0) създава числата от 0 до 11, а EDATE добавя съответния брой месеци към 1 януари 2026. Получавате първия ден на всеки месец, от A2 до A13. Задайте на A2:A13 персонализирания формат mmmm yyyy (чрез Още формати, Персонализиран, вижте Собствени числови формати: „12 бр.“, суми в хиляди, червено при отрицателни стойности), и ще се покаже януари 2026, февруари 2026 и т.н.

Форматът на дата mmmm yyyy
Персонализираният формат mmmm yyyy показва месеца изцяло заедно с годината

Стъпка 2: оборотът по месеци

Въведете в B2:

=SUMIFS(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&EOMONTH($A2;0))

SUMIFS сумира сумите, при които датата е по-голяма или равна на първия ден от месеца и по-малка или равна на последния ден (EOMONTH с 0 връща края на същия месец). Изтеглете формулата до B13 или маркирайте B2:B13, преди да въведете формулата, и завършете с Ctrl+Enter.

Стъпка 3: по продукти

Поставете имената на продуктите като заглавия един до друг, например Rozen в C1, Tulpen в D1 и Boeket в E1, и въведете в C2:

=SUMIFS(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&EOMONTH($A2;0);Verkoop!$B$2:$B$300;C$1)

Добавя се още една двойка условия: продуктът трябва да съвпада със заглавието. Обърнете внимание на знаците за долар: $A2 фиксира колоната с месеците, C$1 реда със заглавията. Така една и съща формула може да стои в цялата област. Бързо: първо маркирайте C2:E13, въведете формулата и натиснете Ctrl+Enter. Euro-Office поставя формулата във всички маркирани клетки, като препратките се коригират за всяка клетка.

Оборот по месеци и по продукти
Сумирано по месеци и по продукти. В лентата за формули е формулата от C2, която чрез C$1 сочи към заглавието Rozen (1)

Броене вместо сумиране

Броя на продажбите за месец изчислявате със същите условия и COUNTIFS:

=COUNTIFS(Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&EOMONTH($A2;0))

Произволен период

Въведете начална дата в H1 и крайна дата в I1. Оборотът между тях, като двата дни се включват:

=SUMIFS(Verkoop!D:D;Verkoop!A:A;">="&H1;Verkoop!A:A;"<="&I1)

Често срещани грешки

  • Кавички и &: сравнението е в кавички, а клетката се добавя след него с &: ">="&H1. Ако въведете ">=H1", Euro-Office търси текста H1 и резултатът е 0.
  • Дати с час (16-11-2026 14:32) в последния ден от месеца остават извън "<="&EOMONTH(...), защото тя връща полунощ. В такъв случай използвайте като второ условие "<"&EDATE($A2;1): по-малко от първия ден на следващия месец.
  • Филтриране само по номер на месеца, например с MONTH() в помощна колона, събира заедно януари 2025 и януари 2026. Винаги включвайте и годината.
  • Дати, записани като текст, не се включват в изчислението. Вижте Дати, които се въвеждат като текст или при които денят и месецът са разменени.

Моля, изчакайте…

Настройте домейните си

За всеки домейн настройте сървърите за имена, връзката с хостинга и кой ще бъде собственикът.

Домейните Ви се зареждат…