Ir diretamente para o conteúdo

Definições de cookies

Escolha que tipos de cookies permite. Pode alterar a sua escolha a qualquer momento em Definições de cookies, no fundo de cada página. Política de privacidade

Necessários

Sempre ativos

Necessários para iniciar sessão, manter o seu carrinho e memorizar as suas escolhas. Estão sempre ativos.

Que cookies?
  • weboke_sessie, weboke_klant, weboke_remember: a sua sessão e manter a sessão iniciada
  • weboke_basket: o seu carrinho
  • wkBtwIncl: mostrar preços com ou sem IVA
  • wok_cookies: a sua escolha de cookies, 12 meses

Mede que anúncio leva a uma visita ou encomenda, para não pagarmos por anúncios que não dão resultado.

Que cookies?
  • Google Ads via Google Tag Manager (_gcl_au, _gcl_aw), até 90 dias
  • OpenAI Ads, anúncios no ChatGPT
  • wok_aff: através de que parceiro chegou até nós (programa de afiliados), 60 dias

4,6

País e idioma

Cada país tem o seu próprio site, com os preços e o IVA desse país.

Ver

Comparar duas listas: quem consta numa e não na outra?

A lista de sócios face aos pagamentos, os clientes do ano passado face aos deste ano, a lista de inventário face à encomenda: quer saber quem consta numa lista e não na outra. Encontrar e remover clientes duplicados procura duplicados dentro de uma só lista; aqui compara duas listas entre si.

Como exemplo, usamos a Bakkerij De Korenaar com duas folhas de cálculo: Klanten2025, com os endereços de e-mail do ano passado em A2:A8, e Klanten2026, com os deste ano em A2:A7.

Método 1: uma coluna auxiliar com saiu ou fica

Na folha Klanten2025, escreva em B2:

=SE(CONTAR.SE(Klanten2026!$A$2:$A$7;A2)=0;"saiu";"fica")

Arraste a fórmula até ao último cliente. CONTAR.SE conta quantas vezes o endereço aparece na lista de 2026. Se o resultado for 0, o cliente saiu. Depois pode filtrar ou ordenar pela coluna B (consulte Classificar e Filtrar).

Os cifrões são importantes: sem eles, o intervalo da outra lista desloca-se ao arrastar a fórmula e os endereços de cima deixam de ser incluídos.

Método 2: uma lista apenas com as diferenças

Numa folha à parte, FILTRAR cria de uma só vez uma lista de todos os clientes que saíram:

=FILTRAR(Klanten2025!A2:A8;CONTAR.SE(Klanten2026!A2:A7;Klanten2025!A2:A8)=0;"ninguém saiu")

Aqui, CONTAR.SE recebe uma lista inteira como segundo argumento e conta para cada endereço de 2025 em simultâneo. FILTRAR mantém os endereços para os quais o resultado é 0. Para encontrar os clientes novos, troque as listas:

=FILTRAR(Klanten2026!A2:A7;CONTAR.SE(Klanten2025!A2:A8;Klanten2026!A2:A7)=0;"nenhum novo")

Clientes que saíram e clientes novos lado a lado
Clientes que saíram (1) e clientes novos (2), cada um com uma única fórmula FILTRAR

Quem consta em apenas uma das duas listas, novo ou que saiu, obtém-se com:

=EXCLUSIVOS(JUNTARV(Klanten2025!A2:A8;Klanten2026!A2:A7);;1)

JUNTARV coloca as duas listas uma por baixo da outra. EXCLUSIVOS com um 1 como terceiro argumento mantém apenas os valores que aparecem exatamente uma vez. Se um endereço já estiver duplicado dentro de uma das listas, torne primeiro essa lista única: =EXCLUSIVOS(JUNTARV(EXCLUSIVOS(Klanten2025!A2:A8);EXCLUSIVOS(Klanten2026!A2:A7));;1).

Método 3: cores em vez de listas

  1. Na folha Klanten2025, selecione os endereços, A2:A8.
  2. No separador Base, escolha Formatação condicional, Nova Regra, tipo Fórmula.
  3. Escreva =CONTAR.SE(Klanten2026!$A$2:$A$7;$A2)=0, escolha uma cor de preenchimento e clique em OK.

Uma referência a outra folha numa regra de formatação funciona sem problemas no Euro-Office; nas versões antigas do Excel era necessário recorrer a um nome definido.

Clientes que saíram assinalados a cor
Os endereços que já não aparecem em 2026 ficam a laranja; a coluna B indica saiu ou fica

Armadilhas

  • Espaços: "info@dekorenaar.nl " com um espaço no fim é, para a folha de cálculo, um endereço diferente. Elimine primeiro os espaços com COMPACTAR numa coluna auxiliar.
  • Células vazias num intervalo também contam como valor. Inclua, portanto, apenas as linhas com dados, ou exclua as células vazias com <>"".
  • Números face a texto: se comparar números de cliente e o número estiver numa lista como texto (alinhado à esquerda na célula) e na outra como número, não haverá correspondência. Consulte PROCV devolve #N/A: como resolver.
  • Não escreva VERDADEIRO sem parênteses como terceiro argumento de EXCLUSIVOS; o Euro-Office só reconhece TRUE, VERDADEIRO() ou 1 (consulte Fórmulas vindas do Excel: nomes de funções portugueses e o ponto e vírgula).

Um momento…

Configurar os seus domínios

Para cada domínio, defina os servidores de nomes, a ligação ao seu alojamento e quem fica como titular.

A carregar os seus domínios…