Ir diretamente para o conteúdo

Definições de cookies

Escolha que tipos de cookies permite. Pode alterar a sua escolha a qualquer momento em Definições de cookies, no fundo de cada página. Política de privacidade

Necessários

Sempre ativos

Necessários para iniciar sessão, manter o seu carrinho e memorizar as suas escolhas. Estão sempre ativos.

Que cookies?
  • weboke_sessie, weboke_klant, weboke_remember: a sua sessão e manter a sessão iniciada
  • weboke_basket: o seu carrinho
  • wkBtwIncl: mostrar preços com ou sem IVA
  • wok_cookies: a sua escolha de cookies, 12 meses

Mede que anúncio leva a uma visita ou encomenda, para não pagarmos por anúncios que não dão resultado.

Que cookies?
  • Google Ads via Google Tag Manager (_gcl_au, _gcl_aw), até 90 dias
  • OpenAI Ads, anúncios no ChatGPT
  • wok_aff: através de que parceiro chegou até nós (programa de afiliados), 60 dias

4,6

País e idioma

Cada país tem o seu próprio site, com os preços e o IVA desse país.

Ver

Somar a faturação por mês ou por período com SOMA.SE.S

Um livro de caixa, uma lista de vendas ou um registo de horas tem uma data por linha. O que pretende saber é o total por mês, por trimestre ou entre duas datas, eventualmente também por produto. Com SOMA.SE.S e duas condições de data cria esse resumo, e ele continua correto quando são acrescentadas linhas. Uma tabela dinâmica também o consegue fazer (consulte Uma tabela dinâmica por mês, trimestre ou semana); SOMA.SE.S é mais prática quando o resumo tem de manter uma forma fixa, por exemplo para um relatório ou um orçamento.

Como exemplo, usamos as vendas da Bloemisterij Het Zonnetje na folha de cálculo Vendas: em A a data, em B o produto, em C a categoria e em D o valor, da linha 2 até à 300.

Passo 1: uma linha de meses

Crie uma folha de cálculo Resumo. Em vez de escrever doze datas, uma única fórmula cria-as todas. Escreva em A2:

=DATAM(DATA(2026;1;1);SEQUÊNCIA(12;1;0))

SEQUÊNCIA(12;1;0) cria os números de 0 a 11, e DATAM soma esse número de meses a 1 de janeiro de 2026. Obtém o primeiro dia de cada mês, de A2 a A13. Atribua a A2:A13 o formato personalizado mmmm aaaa (através de Mais formatos, Personalizado, consulte Formatos de número personalizados: "12 un", valores em milhares, vermelho para negativos), e verá janeiro 2026, fevereiro 2026 e assim sucessivamente.

O formato de data mmmm aaaa
O formato personalizado mmmm aaaa mostra o mês por extenso com o ano

Passo 2: a faturação por mês

Escreva em B2:

=SOMA.SE.S(Vendas!$D$2:$D$300;Vendas!$A$2:$A$300;">="&$A2;Vendas!$A$2:$A$300;"<="&FIMMÊS($A2;0))

SOMA.SE.S soma os valores cuja data é maior ou igual ao primeiro dia do mês e menor ou igual ao último dia (FIMMÊS com 0 devolve o fim do mesmo mês). Arraste a fórmula até B13, ou selecione B2:B13 antes de escrever e termine com Ctrl+Enter.

Passo 3: por produto

Coloque os nomes dos produtos como cabeçalhos lado a lado, por exemplo Rosas em C1, Tulipas em D1 e Ramo em E1, e escreva em C2:

=SOMA.SE.S(Vendas!$D$2:$D$300;Vendas!$A$2:$A$300;">="&$A2;Vendas!$A$2:$A$300;"<="&FIMMÊS($A2;0);Vendas!$B$2:$B$300;C$1)

É acrescentado um par de condições: o produto tem de ser igual ao cabeçalho. Atenção aos cifrões: $A2 fixa a coluna dos meses, C$1 a linha dos cabeçalhos. Assim, a mesma fórmula pode estar em toda a área. Mais rápido: selecione primeiro C2:E13, escreva a fórmula e prima Ctrl+Enter. O Euro-Office coloca então a fórmula em todas as células selecionadas, com as referências ajustadas a cada célula.

Faturação por mês e por produto
Somado por mês e por produto. Na barra de fórmulas, a fórmula de C2, que com C$1 consulta o cabeçalho Rosas (1)

Contar em vez de somar

O número de vendas por mês conta-se com as mesmas condições e CONTAR.SE.S:

=CONTAR.SE.S(Vendas!$A$2:$A$300;">="&$A2;Vendas!$A$2:$A$300;"<="&FIMMÊS($A2;0))

Um período livre

Coloque uma data de início em H1 e uma data de fim em I1. A faturação entre ambas, incluindo os dois dias:

=SOMA.SE.S(Vendas!D:D;Vendas!A:A;">="&H1;Vendas!A:A;"<="&I1)

Armadilhas

  • Aspas e &: a comparação fica entre aspas e a célula vem a seguir com &: ">="&H1. Se escrever ">=H1", o Euro-Office procura o texto H1 e o resultado é 0.
  • Datas com hora (16/11/2026 14:32) no último dia do mês ficam de fora de "<="&FIMMÊS(...), porque esse valor corresponde à meia-noite. Nesse caso, utilize como segunda condição "<"&DATAM($A2;1): menor do que o primeiro dia do mês seguinte.
  • Filtrar apenas pelo número do mês, por exemplo com MÊS() numa coluna auxiliar, soma janeiro de 2025 e janeiro de 2026 em conjunto. Inclua sempre o ano.
  • Datas em formato de texto não são contabilizadas. Consulte Datas que chegam como texto ou com o dia e o mês trocados.

Um momento…

Configurar os seus domínios

Para cada domínio, defina os servidores de nomes, a ligação ao seu alojamento e quem fica como titular.

A carregar os seus domínios…