Към съдържанието

Настройки за бисквитки

Изберете кои видове бисквитки разрешавате. Можете да промените избора си по всяко време чрез „Настройки за бисквитки“ в долната част на всяка страница. Декларация за поверителност

Необходими

Винаги включени

Нужни са за вход, за запазване на количката и на Вашите избори. Те са винаги включени.

Кои бисквитки?
  • weboke_sessie, weboke_klant, weboke_remember: Вашата сесия и оставането в акаунта
  • weboke_basket: Вашата количка
  • wkBtwIncl: показване на цените с или без ДДС
  • wok_cookies: Вашият избор за бисквитките, 12 месеца

Измерват коя реклама води до посещение или поръчка, за да не плащаме за реклами без резултат.

Кои бисквитки?
  • Google Ads чрез Google Tag Manager (_gcl_au, _gcl_aw), до 90 дни
  • OpenAI Ads, реклами в ChatGPT
  • wok_aff: кой партньор Ви е препратил към нас (партньорска програма), 60 дни

4,6

Държава и език

Всяка държава има собствен сайт, с цените и ДДС на тази държава.

Преглед

Omzet per maand of per periode optellen met SOMMEN.ALS

Тази статия все още не е преведена. Четете холандската версия.

Een kassaboek, verkooplijst of urenregistratie heeft een datum per regel. Wat je wilt weten is het totaal per maand, per kwartaal of tussen twee datums, eventueel ook nog per product. Met SOMMEN.ALS en twee datumvoorwaarden maak je zo'n overzicht, en het blijft kloppen als er regels bij komen. Een draaitabel kan het ook (zie Een draaitabel per maand, kwartaal of week); SOMMEN.ALS is handiger als het overzicht een vaste vorm moet houden, bijvoorbeeld voor een rapport of een begroting.

Als voorbeeld nemen we de verkoop van Bloemisterij Het Zonnetje op het werkblad Verkoop: in A de datum, in B het product, in C de categorie en in D het bedrag, van rij 2 tot en met 300.

Stap 1: een rij met maanden

Maak een werkblad Overzicht. In plaats van twaalf datums te typen, maakt één formule ze allemaal. Typ in A2:

=ZELFDE.DAG(DATUM(2026;1;1);REEKS(12;1;0))

REEKS(12;1;0) maakt de getallen 0 tot en met 11, en ZELFDE.DAG telt zoveel maanden op bij 1 januari 2026. Je krijgt de eerste dag van elke maand, van A2 tot en met A13. Geef A2:A13 de aangepaste notatie mmmm jjjj (via Meer indelingen, Aangepast, zie Eigen getalnotaties: "12 st", bedragen in duizenden, rood bij negatief), dan staat er januari 2026, februari 2026 enzovoort.

De datumnotatie mmmm jjjj
De aangepaste notatie mmmm jjjj toont de maand voluit met het jaar

Stap 2: de omzet per maand

Typ in B2:

=SOMMEN.ALS(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&LAATSTE.DAG($A2;0))

SOMMEN.ALS telt de bedragen op waarbij de datum groter dan of gelijk is aan de eerste dag van de maand, én kleiner dan of gelijk aan de laatste dag (LAATSTE.DAG met 0 geeft het einde van dezelfde maand). Trek de formule door tot B13, of selecteer B2:B13 voordat je typt en sluit af met Ctrl+Enter.

Stap 3: per product

Zet productnamen als kopjes naast elkaar, bijvoorbeeld Rozen in C1, Tulpen in D1 en Boeket in E1, en typ in C2:

=SOMMEN.ALS(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&LAATSTE.DAG($A2;0);Verkoop!$B$2:$B$300;C$1)

Er komt één voorwaardenpaar bij: het product moet gelijk zijn aan het kopje. Let op de dollartekens: $A2 houdt de kolom met maanden vast, C$1 de rij met kopjes. Daardoor kan dezelfde formule in het hele vlak staan. Snel: selecteer eerst C2:E13, typ de formule en druk op Ctrl+Enter. Euro-Office zet de formule dan in alle geselecteerde cellen, met de verwijzingen per cel aangepast.

Omzet per maand en per product
Per maand en per product opgeteld. In de formulebalk de formule van C2, die met C$1 naar het kopje Rozen (1) kijkt

Tellen in plaats van optellen

Het aantal verkopen per maand tel je met dezelfde voorwaarden en AANTALLEN.ALS:

=AANTALLEN.ALS(Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&LAATSTE.DAG($A2;0))

Een vrije periode

Zet een begindatum in H1 en een einddatum in I1. De omzet daartussen, beide dagen meegerekend:

=SOMMEN.ALS(Verkoop!D:D;Verkoop!A:A;">="&H1;Verkoop!A:A;"<="&I1)

Valkuilen

  • Aanhalingstekens en &: de vergelijking staat tussen aanhalingstekens en de cel komt erachter met &: ">="&H1. Typ je ">=H1", dan zoekt Euro-Office naar de tekst H1 en is de uitkomst 0.
  • Datums met een tijd erin (16-11-2026 14:32) vallen op de laatste dag van de maand buiten "<="&LAATSTE.DAG(...), want die is middernacht. Gebruik dan als tweede voorwaarde "<"&ZELFDE.DAG($A2;1): kleiner dan de eerste dag van de volgende maand.
  • Alleen op maandnummer filteren, bijvoorbeeld met MAAND() in een hulpkolom, telt januari 2025 en januari 2026 bij elkaar. Neem het jaar altijd mee.
  • Datums als tekst tellen niet mee. Zie Дати, които се въвеждат като текст или при които денят и месецът са разменени.

Моля, изчакайте…

Настройте домейните си

За всеки домейн настройте сървърите за имена, връзката с хостинга и кой ще бъде собственикът.

Домейните Ви се зареждат…