Aller au contenu

Paramètres des cookies

Choisissez, par catégorie, les cookies que vous autorisez. Vous pouvez modifier votre choix à tout moment via Paramètres des cookies, en bas de chaque page. Politique de confidentialité

Nécessaires

Toujours activés

Indispensables pour vous connecter, conserver votre panier et mémoriser vos choix. Ils sont toujours activés.

Quels cookies ?
  • weboke_sessie, weboke_klant, weboke_remember: votre session et le maintien de la connexion
  • weboke_basket: votre panier
  • wkBtwIncl: l'affichage des prix TTC ou HT
  • wok_cookies: votre choix concernant les cookies, 12 mois

Mesure quelle publicité mène à une visite ou à une commande, pour que nous ne payions pas des publicités inefficaces.

Quels cookies ?
  • Google Ads via Google Tag Manager (_gcl_au, _gcl_aw), jusqu'à 90 jours
  • OpenAI Ads, publicités dans ChatGPT
  • wok_aff: le partenaire qui vous a orienté vers nous (programme d'affiliation), 60 jours

4,6

Pays et langue

Chaque pays a son propre site, avec les prix et la TVA de ce pays.

Afficher

Des listes qui se mettent à jour toutes seules avec FILTRE, UNIQUE et TRIER

Regarder la vidéo courte

Des listes qui se mettent à jour toutes seules avec FILTRE, UNIQUE et TRIER 1:47

Une liste de clients sans doublons, un aperçu de toutes les commandes en attente, une liste de produits classée par chiffre d'affaires : autrefois, vous créiez ce type de liste en copiant, filtrant et triant, puis vous recommenciez dès que quelque chose changeait. Avec les fonctions FILTRE, UNIQUE et TRIER, vous écrivez une seule formule qui crée toute la liste et la met à jour automatiquement. Euro-Office prend en charge ces matrices dites dynamiques : le résultat « se propage » sur autant de cellules que nécessaire.

Prenons comme exemple la feuille Bestellingen de la Bakkerij De Korenaar : en A la date, en B le client, en C le produit, en D le montant et en E l'état du paiement (ja ou nee, c'est-à-dire oui ou non).

Une liste de clients unique et triée

Saisissez en G2 =TRIER(UNIQUE(FILTRE(B2:B500;B2:B500<>""))) et appuyez sur Entrée. C'est tout : vous obtenez chaque client une seule fois, par ordre alphabétique, les uns sous les autres à partir de G2.

  • FILTRE(B2:B500;B2:B500<>"") ignore les lignes vides. Vous pouvez ainsi prévoir une plage large pour les commandes qui s'ajouteront plus tard.
  • UNIQUE supprime les doublons.
  • TRIER les classe dans l'ordre.
Une liste de clients unique qui se propage sur plusieurs cellules
La formule se trouve uniquement en G2 (1), voir la barre de formule ; le résultat se propage jusqu'au dernier client, y compris Tandarts Bos de la ligne 14

Si une commande d'un nouveau client s'ajoute, par exemple Tandarts Bos en ligne 14, celui-ci apparaît immédiatement au bon endroit dans la liste. Pour modifier la liste, modifiez la formule dans la première cellule, G2.

Toutes les commandes en attente de ce mois-ci

FILTRE peut aussi récupérer des lignes entières, avec plusieurs conditions :

=FILTRE(A2:D500;(E2:E500="nee")*(A2:A500>=FIN.MOIS(AUJOURDHUI();-1)+1);"rien en attente")

  • Le premier élément correspond à ce que vous souhaitez afficher : les colonnes A à D.
  • Le deuxième élément contient les conditions. Chaque condition est placée entre parenthèses. Un * entre elles signifie et, un + signifie ou.
  • FIN.MOIS(AUJOURDHUI();-1)+1 correspond au premier jour du mois en cours.
  • Le troisième élément est le texte affiché s'il n'y a aucun résultat.
FILTRE avec deux conditions
Les commandes en attente de ce mois-ci à partir de I2 ; remarquez les montants de la colonne L, affichés sous forme de date

Attention : le résultat ne reprend pas le format de votre liste. Les montants reçoivent généralement le format Général : 64,50 € s'affiche alors 64,5. Parfois, l'ensemble du résultat prend le format de la première colonne et les montants s'affichent sous forme de date, comme dans l'image : 36,00 devient alors 05-02-1900. Dans les deux cas, sélectionnez la colonne des montants dans le résultat et choisissez vous-même le format Monétaire ou Nombre (voir Mettre en forme les nombres, les dates et les devises).

Trier et choisir des colonnes

  • Par montant, le plus élevé en premier : =TRIER(FILTRE(A2:D500;E2:E500="nee");4;-1). Le 4 désigne la quatrième colonne du résultat, -1 signifie un tri décroissant.
  • Trier selon une colonne que vous n'affichez pas : =TRIERPAR(FILTRE(B2:B500;E2:E500="nee");FILTRE(D2:D500;E2:E500="nee");-1) renvoie uniquement les noms des clients, triés par montant.
  • Uniquement le client et le montant : =CHOISIRCOLS(FILTRE(A2:D500;E2:E500="nee");2;4).

Astuce : lors de la démonstration, l'ordre d'une formule existante =TRIER(FILTRE(...);4;-1) s'est mélangé après l'ajout d'une commande sous la liste. Une formule saisie après l'ajout trie en revanche correctement. Vérifiez donc l'ordre lorsque des lignes ont été ajoutées. S'il n'est pas correct, saisissez à nouveau la formule : cliquez sur la cellule contenant la formule, appuyez sur F2 puis sur Entrée.

Quelque chose bloque le résultat

Si une cellule où le résultat doit s'afficher contient déjà quelque chose, la liste ne peut pas se propager. Dans Excel, vous voyez alors la valeur d'erreur #PROPAGATION!. Euro-Office laisse alors la cellule de la formule vide ; si vous cliquez dessus, une ligne pointillée entoure la zone où le résultat doit s'afficher. Videz les cellules de cette zone et la liste apparaît immédiatement. Laissez donc de l'espace libre sous une telle formule et à côté.

Un résultat qui ne peut pas se propager
La formule en G2 (1) reste vide : en G4 (2), le texte blokkade bloque le passage. La ligne pointillée indique où la liste doit s'afficher

Calculer avec des colonnes entières dans une seule formule

Certaines formules calculent avec une colonne entière à la fois, comme =SOMME(D2:D13*(E2:E13="nee")) : les montants de toutes les commandes qui ne sont pas encore payées, ici 258,50. Dans Euro-Office, une telle formule fonctionne avec un simple Entrée. Les formules avec SI sur une colonne entière à l'intérieur d'une autre fonction, comme =GRANDE.VALEUR(SI(B2:B37="Taart";C2:C37);1), ne sont pas calculées correctement par Euro-Office avec un simple Entrée : vous obtenez #NOMBRE! ou un nombre erroné. Validez une telle formule avec Ctrl+Maj+Entrée. La formule reçoit alors des accolades {…} et donne le bon résultat. Souvent, vous pouvez aussi vous passer de SI en utilisant FILTRE : =GRANDE.VALEUR(FILTRE(C2:C37;B2:B37="Taart");1).

Ce qui n'est pas possible

  • LET et LAMBDA, ainsi que les fonctions qui en dépendent comme BYROW, MAP et GROUPBY, ne sont pas prises en charge par Euro-Office. Un fichier Excel contenant ces fonctions affiche #NOM?. Utilisez une colonne auxiliaire, ou consultez Formules Excel avec LET ou LAMBDA : que faire à la place dans Euro-Office pour savoir comment procéder autrement.
  • Un collègue qui utilise Excel 2019 ou une version antérieure voit #NOM? pour ces fonctions.

Pièges à éviter

Un instant…

Configurez vos domaines

Pour chaque domaine, réglez les serveurs de noms, l'association à votre hébergement et le futur titulaire.

Chargement de vos domaines…